Tips - WSH

 【TOP】
期限付きメッセージボックス
WshShell.Popup メソッドを用いると、期限付きのメッセージボックスを表示させることができます。
このメッセージボックスは wscript、cscript に関係なくポップアップ表示されますので、バッチプログラム等で
使うときには少し注意が必要です。
Popup メソッドの構文を下記に示します。

buttonCode = WshShell.Popup( message, [timeToWait], [title], [type])
message: メッセージボックスに表示する文字列です。
timeToWait: 省略可能。ユーザの応答を待つ時間（秒）です。
0 にすると、ユーザの応答があるまで表示されます。
title: 省略可能。メッセージボックスのタイトルです。省略時は「Windows Script Host」となります。
type: 省略可能。ボタンの種類やアイコン等を指定します。
詳細は例を参照してください。
buttonCode: Popup メソッドの戻り値です。ユーザが押下したボタンのコードが格納されます。
timeToWait 秒以内に応答がないと、「-1」が戻り値となります。
Popup メソッドの例を以下に示します。

Dim WshShell, ButtonCode

'--表示するボタンの種類--
Const MB_OK = &H0                  '「OK」
Const MB_OKCANCEL = &H1            '「OK」「キャンセル」
Const MB_ABORTRETRYIGNORE = &H2    '「中止」「再試行」「無視」
Const MB_YESNOCANCEL = &H3         '「はい」「いいえ」「キャンセル」
Const MB_YESNO = &H4               '「はい」「いいえ」
Const MB_RETRYCANCEL = &H5         '「再試行」「キャンセル」

'--表示するアイコンの種類--
Const MB_ICONSTOP = &H10           '「×」
Const MB_ICONQUESTION = &H20       '「？」
Const MB_ICONEXCLAMATION = &H30    '「！」
Const MB_ICONINFORMATION = &H40    '「ｉ」

'--デフォルトのボタンフラグ--
Const MB_DEFBUTTON1 = &H0          ' 最初のボタンをデフォルトにする
Const MB_DEFBUTTON2 = &H100        ' 2番目のボタンをデフォルトにする
Const MB_DEFBUTTON3 = &H200        ' 3番目のボタンをデフォルトにする

'--押下されたボタンコード--
Const IDOK = &H1                   '「OK」
Const IDCANCEL = &H2               '「キャンセル」
Const IDABORT = &H3                '「中止」
Const IDRETRY = &H4                '「再試行」
Const IDIGNORE = &H5               '「無視」
Const IDYES = &H6                  '「はい」
Const IDNO = &H7                   '「いいえ」
Const IDTIMEOUT = &HFFFF           ' 時間切れ

Set WshShell = WScript.CreateObject("WScript.Shell")

ButtonCode =  _
    WshShell.Popup("朝ご飯食べました？", 5, "質問です", MB_YESNO + MB_ICONQUESTION + MB_DEFBUTTON2)

Select Case ButtonCode
    Case IDYES
        WScript.Echo "健康的でいいですね！"
    Case IDNO
        WScript.Echo "私もです。"
    Case IDTIMEOUT
        WScript.Echo "もしも～し？"
End Select

Set WshShell = Nothing
【戻る】